1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107

{ pkgs, lib, drvSeqL, ... }:

let
  # Build a rust executable, $out is the executable.
  rustSimple = args@{ name, ... }: src: pkgs.runCommandLocal "rust-simple_${name}" { } ''
    mkdir -p $out/bin
    ln -s "${rustSimpleBin args src}/bin/${name}" $out/bin/${name}
    find $out
  '';

  # Like `rustSimple`, but put the binary in `$out/bin/`.
  rustSimpleBin =
    { name
    , dependencies ? [ ]
    , doCheck ? true
    }: src:
    (if doCheck then testRustSimple else pkgs.lib.id)
      (pkgs.buildRustCrate ({
        pname = name;
        version = "1.0.0";
        crateName = name;
        crateBin = [ name ];
        dependencies = dependencies;
        src = pkgs.runCommandLocal "write-main.rs"
          {
            src = src;
            passAsFile = [ "src" ];
          } ''
          mkdir -p $out/src/bin
          cp "$srcPath" $out/src/bin/${name}.rs
          find $out
        '';
      }));

  # Build a rust library, that can be used as dependency to `rustSimple`.
  # Wrapper around `pkgs.buildRustCrate`, takes all its arguments.
  rustSimpleLib =
    { name
    , dependencies ? [ ]
    , doCheck ? true
    }: src:
    (if doCheck then testRustSimple else pkgs.lib.id)
      (pkgs.buildRustCrate ({
        pname = name;
        version = "1.0.0";
        crateName = name;
        dependencies = dependencies;
        src = pkgs.runCommandLocal "write-lib.rs"
          {
            src = src;
            passAsFile = [ "src" ];
          } ''
          mkdir -p $out/src
          cp "$srcPath" $out/src/lib.rs
          find $out
        '';
      }));

  rustFullLib = args@{ name, src, doCheck ? true, libPath ? "src/lib.rs",  dependencies ? [ ] }:
    (if doCheck then testRustSimple else pkgs.lib.id)
      (pkgs.buildRustCrate {
        pname = name;
        version = "1.0.0";
        crateName = name;
        edition = "2021";
        buildTests = true;

        inherit src;
        inherit libPath;
        inherit dependencies;
      });

  /* Takes a `buildRustCrate` derivation as an input,
    * builds it with `{ buildTests = true; }` and runs
    * all tests found in its `tests` dir. If they are
    * all successful, `$out` will point to the crate
    * built with `{ buildTests = false; }`, otherwise
    * it will fail to build.
    *
    * See also `nix.drvSeqL` which is used to implement
    * this behavior.
    */
  testRustSimple = rustDrv:
    let
      crate = buildTests: rustDrv.override { inherit buildTests; };
      tests = pkgs.runCommandLocal "${rustDrv.name}-tests-run" { }
        ''
          set -euo pipefail
          ls ${crate true}/tests
          for test in $(find "${crate true}/tests" -type f -executable); do
            echo "Running test $test"
            $test
          done
          touch "$out"
        '';
    in
    drvSeqL [ tests ] (crate false);

in
{
  inherit
    rustSimple
    rustSimpleBin
    rustSimpleLib
    rustFullLib
    ;
}