1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163

ls = find_program('ls', native : true)

test_confdata = {
  'bindir': bindir,
  'ls': fs.parent(ls.full_path()),
  'lsof': lsof.full_path(),
  'dot': dot.found() ? dot.full_path() : '',
  'bash': bash.full_path(),
  'sandbox_shell': busybox.found() ? busybox.full_path() : '',
  'PACKAGE_VERSION': meson.project_version(),
  'system': host_system,
  'python': python.full_path(),
  'runinpty': runinpty.full_path(),
}

# Just configures `common/vars-and-functions.sh.in`.
# Done as a subdir() so Meson places it under `common` in the build directory as well.
subdir('common')

config_nix_in = configure_file(
  input : 'config.nix.in',
  output : 'config.nix',
  configuration : test_confdata,
)

# Just configures `nix-shell/config.nix.in`. Done as a subdir() for the same reason as above.
subdir('nix-shell')

subdir('plugins')
subdir('test-libstoreconsumer')

functional_tests_scripts = [
  'init.sh',
  'test-infra.sh',
  'gc.sh',
  'nix-collect-garbage-d.sh',
  'nix-collect-garbage-dry-run.sh',
  'remote-store.sh',
  'legacy-ssh-store.sh',
  'experimental-features.sh',
  'gc-auto.sh',
  'user-envs.sh',
  'binary-cache.sh',
  'binary-cache-regression-fj647.sh',
  'multiple-outputs.sh',
  'nix-build.sh',
  'gc-concurrent.sh',
  'repair.sh',
  'repair-chroot.sh',
  'fixed.sh',
  'export-graph.sh',
  'fetchGitRefs.sh',
  'gc-runtime.sh',
  'fetchers.sh',
  'fetchGit.sh',
  'fetchGitLocked.sh',
  'fetchurl.sh',
  'fetchPath.sh',
  'fetchTree-file.sh',
  'referrers.sh',
  'substitute-with-invalid-ca.sh',
  'signing.sh',
  'gc-non-blocking.sh',
  'check.sh',
  'nix-shell/basic.sh',
  'nix-shell/structured-attrs.sh',
  'nix-shell/regression-533.sh',
  'build-remote-input-addressed.sh',
  'secure-drv-outputs.sh',
  'restricted.sh',
  'fetchGitSubmodules.sh',
  'readfile-context.sh',
  'nix-channel.sh',
  'dependencies.sh',
  'check-reqs.sh',
  'build-remote-content-addressed-fixed.sh',
  'nar-access.sh',
  'repl.sh',
  'binary-cache-build-remote.sh',
  'logging.sh',
  'export.sh',
  'config.sh',
  'filter-source.sh',
  'misc.sh',
  'linux-sandbox.sh',
  'supplementary-groups.sh',
  'build-dry.sh',
  'structured-attrs.sh',
  'shell.sh',
  'nix-copy-ssh.sh',
  'nix-copy-ssh-ng.sh',
  'pre-hook.sh',
  'post-hook.sh',
  'eval-store.sh',
  'derivation-json.sh',
  'db-migration.sh',
  'bash-profile.sh',
  'flakes/show.sh',
  'read-only-store.sh',
  'nested-sandboxing.sh',
  'test-libstoreconsumer.sh',
  'extra-sandbox-profile.sh',
  'regression-484.sh',
  'redirected-filter-source.sh',
]

# Plugin tests require shared libraries support.
if get_option('default_library') != 'static'
  functional_tests_scripts += ['plugins.sh']
endif

if get_option('default_library') != 'static' and get_option('enable-contrib-plugins')
  functional_tests_scripts += [
    'mtls-substituter-ssl-client-cert.sh'
  ]
endif

# TODO(Qyriad): this will hopefully be able to be removed when we remove the autoconf+Make
# buildsystem. See the comments at the top of setup-functional-tests.py for why this is here.
meson.add_install_script(
  python,
  meson.project_source_root() / 'meson/setup-functional-tests.py',
)

foreach script : functional_tests_scripts
  # Turns, e.g., `tests/functional/flakes/show.sh` into a Meson test target called
  # `functional-flakes-show`.
  name = 'functional-@0@'.format(fs.replace_suffix(script, '')).replace('/', '-')

  extra_deps = []
  if script == 'plugins.sh'
    extra_deps += [
      # Set in tests/functional/plugins/meson.build
      libplugintest,
      libplugintestfail,
    ]
  elif script == 'test-libstoreconsumer.sh'
    extra_deps += [
      # Set in tests/functional/test-libstoreconsumer/meson.build
      libstoreconsumer_tester,
    ]
  endif

  test(
    name,
    python,
    args: [
      meson.project_source_root() / 'meson/run-test.py',
      script,
    ],
    suite : 'installcheck',
    env : {
      'MESON_BUILD_ROOT': meson.project_build_root(),
    },
    # some tests take 15+ seconds even on an otherwise idle machine, on a loaded machine
    # this can easily drive them to failure. give them more time, 5min rather than 30sec
    timeout : 300,
    # Used for target dependency/ordering tracking, not adding compiler flags or anything.
    depends : extra_deps,
  )
endforeach

subdir('repl_characterization')