1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

{ lib
, stdenvNoCC
, fetchFromSyndicateLang
, tcl9Packages
, installShellFiles
}:

let
  inherit (tcl9Packages) tcl sycl;
in
stdenvNoCC.mkDerivation (finalAttrs: {
  pname = "synit-service";
  version = "0.1";

  src = fetchFromSyndicateLang {
    owner = "synit";
    repo = "synit-service";
    tag = finalAttrs.version;
    hash = "sha256-kZRGzNmTyRTzYmZGXtdIf6qC8CyoOCDRg4mQvvXbdzM=";
  };

  buildInputs = [
    tcl
    sycl
  ];

  nativeBuildInputs = [
    installShellFiles
  ];

  buildPhase = ''
    runHook preBuild
    sed '2i lappend auto_path ${sycl}/lib/${sycl.name}' <service.tcl >service
    runHook postBuild
  '';

  installPhase = ''
    runHook preInstall
    install -m755 -D -t $out/bin service
    installShellCompletion --fish --cmd service completions/service.fish
    runHook postInstall
  '';

  meta = {
    description = "Synit service management utility";
    maintainers = with lib.maintainers; [ ehmry ];
    mainProgram = "service";
    license = lib.licenses.unlicense;
  };
})